first commit

powermy.zsh-theme

@@ -0,0 +1,231 @@
+# vim:ft=zsh ts=2 sw=2 sts=2
+#
+#
+# # README
+#
+# In order for this theme to render correctly, you will need a
+# [Powerline-patched font](https://github.com/Lokaltog/powerline-fonts).
+#
+#
+# # Goals
+#
+# The aim of this theme is to only show you *relevant* information. Like most
+# prompts, it will only show git information when in a git working directory.
+# However, it goes a step further: everything from the current user and
+# hostname to whether the last call exited with an error to whether background
+# jobs are running in this shell will all be displayed automatically when
+# appropriate.
+
+### Segment drawing
+# A few utility functions to make it easy and re-usable to draw segmented prompts
+
+PREVIOUS_BG='NONE'
+if [[ ( -n "$SSH_CLIENT" || -n "$SSH_TTY" ) ]]; then
+  SEGMENT_SEPARATOR=''
+  SEGMENT_R_SEPARATOR=''
+else
+  SEGMENT_SEPARATOR=''
+  SEGMENT_R_SEPARATOR='\ue0b2'
+fi
+
+CONTEXT_FG_COLOR='white'
+CONTEXT_BG_COLOR='127'
+DIR_FG_COLOR='255'
+DIR_BG_COLOR='243'
+VIRTUALENV_FG_COLOR='236'
+VIRTUALENV_BG_COLOR='green'
+HOUR_FG_COLOR='236'
+HOUR_BG_COLOR='green'
+STATUS_WRONG='red'
+STATUS_OK='green'
+STATUS_ROOT='yellow'
+STATUS_JOBS='cyan'
+STATUS_BG_COLOR='236'
+STATUS_FG_COLOR='default'
+
+# Begin a segment
+# Takes two arguments, background and foreground. Both can be omitted,
+# rendering default background/foreground.
+# an other argument for bold font can be added
+prompt_segment() {
+  local bg fg
+  [[ -n $1 ]] && bg="%K{$1}" || bg="%k"  # set background
+  [[ -n $2 ]] && fg="%F{$2}" || fg="%f"  # set foreground
+  [[ -n $2 && -n $4 ]] && fg="$4%F{$2}" || fg="$fg" # if bold argument set foreground
+  if [[ $PREVIOUS_BG != 'NONE' && $1 != $PREVIOUS_BG ]]; then
+    echo -n " %{$bg%F{$PREVIOUS_BG}%}$SEGMENT_SEPARATOR%{$fg%} "
+  else
+    echo -n "%{$bg%}%{$fg%} "
+  fi
+  PREVIOUS_BG=$1
+  [[ -n $3 ]] && echo -n $3  # write text
+  [[ -n $2 && -n $4 ]] && echo -n "$4:l%F{$2}$bg" # remove bold tag
+}
+
+# End the prompt, closing any open segments
+prompt_end() {
+  if [[ -n $PREVIOUS_BG ]]; then
+    echo -n " %{%k%F{$PREVIOUS_BG}%}$SEGMENT_SEPARATOR"
+  else
+    echo -n "%{%k%}"
+  fi
+  echo -n "%{%f%}"
+  PREVIOUS_BG=''
+}
+
+prompt_right_segment() {
+  local bg fg
+  [[ -n $1 ]] && bg="%K{$1}" || bg="%k"
+  [[ -n $2 ]] && fg="%F{$2}" || fg="%f"
+  if [[ $PREVIOUS_BG != 'NONE' && $1 != $PREVIOUS_BG ]]; then
+    echo -n " %{%F{$1}%}$SEGMENT_R_SEPARATOR%{$bg$fg%} "
+  else
+    echo -n "%{%K{default}%F{$1}%}$SEGMENT_R_SEPARATOR%{$bg$fg%}"
+  fi
+  PREVIOUS_BG=$1
+  [[ -n $3 ]] && echo -n $3
+}
+
+### Prompt components
+# Each component will draw itself, and hide itself if no information needs to be shown
+
+# Context: user@hostname (who am I and where am I)
+prompt_context() {
+  local user=`whoami`
+
+  if [[ "$user" != "$DEFAULT_USER" || -n "$SSH_CLIENT" ]]; then
+    prompt_segment $CONTEXT_BG_COLOR $CONTEXT_FG_COLOR "%(!.%{%F{yellow}%}.)$user@%m" "%B"
+  fi
+}
+
+# Git: branch/detached head, dirty status
+prompt_git() {
+  local ref dirty mode repo_path
+  repo_path=$(git rev-parse --git-dir 2>/dev/null)
+
+  if $(git rev-parse --is-inside-work-tree >/dev/null 2>&1); then
+    dirty=$(parse_git_dirty)
+    ref=$(git symbolic-ref HEAD 2> /dev/null) || ref="➦ $(git show-ref --head -s --abbrev |head -n1 2> /dev/null)"
+    if [[ -n $dirty ]]; then
+      prompt_segment yellow black
+    else
+      prompt_segment green black
+    fi
+
+    if [[ -e "${repo_path}/BISECT_LOG" ]]; then
+      mode=" <B>"
+    elif [[ -e "${repo_path}/MERGE_HEAD" ]]; then
+      mode=" >M<"
+    elif [[ -e "${repo_path}/rebase" || -e "${repo_path}/rebase-apply" || -e "${repo_path}/rebase-merge" || -e "${repo_path}/../.dotest" ]]; then
+      mode=" >R>"
+    fi
+
+    setopt promptsubst
+    autoload -Uz vcs_info
+
+    zstyle ':vcs_info:*' enable git
+    zstyle ':vcs_info:*' get-revision true
+    zstyle ':vcs_info:*' check-for-changes true
+    zstyle ':vcs_info:*' stagedstr '✚ '
+    zstyle ':vcs_info:git:*' unstagedstr '● '
+    zstyle ':vcs_info:*' formats ' %u%c'
+    zstyle ':vcs_info:*' actionformats ' %u%c'
+    vcs_info
+    echo -n "${ref/refs\/heads\// }${vcs_info_msg_0_%% }${mode}"
+  fi
+}
+
+#Mercurial: status of repository
+prompt_hg() {
+  local rev status
+  if $(hg id >/dev/null 2>&1); then
+    if $(hg prompt >/dev/null 2>&1); then
+      if [[ $(hg prompt "{status|unknown}") = "?" ]]; then
+        # if files are not added
+        prompt_segment red white
+        st='±'
+      elif [[ -n $(hg prompt "{status|modified}") ]]; then
+        # if any modification
+        prompt_segment yellow black
+        st='±'
+      else
+        # if working copy is clean
+        prompt_segment green black
+      fi
+      echo -n $(hg prompt "☿ {rev}@{branch}") $st
+    else
+      st=""
+      branch=$(hg id -b 2>/dev/null)
+      if `hg st | grep -Eq "^\?"`; then
+        prompt_segment red black
+        st='±'
+      elif `hg st | grep -Eq "^(M|A)"`; then
+        prompt_segment yellow black
+        st='±'
+      else
+        prompt_segment green black
+      fi
+      echo -n "☿ $branch" $st
+    fi
+  fi
+}
+
+# Dir: current working directory
+prompt_dir() {
+  prompt_segment $DIR_BG_COLOR $DIR_FG_COLOR '%~'
+}
+
+# Virtualenv: current working virtualenv
+prompt_virtualenv() {
+  local virtualenv_path="$VIRTUAL_ENV"
+  if [[ -n $virtualenv_path && -n $VIRTUAL_ENV_DISABLE_PROMPT ]]; then
+    prompt_segment $VIRTUALENV_BG_COLOR $VIRTUALENV_FG_COLOR "\u24d4 `basename $virtualenv_path`"
+  fi
+}
+
+# Status:
+# - was there an error
+# - am I root
+# - are there background jobs?
+prompt_status() {
+  local symbols
+  symbols=()
+  [[ $RETVAL -ne 0 ]] && symbols+="%{%F{$STATUS_WRONG}%}✘"
+  [[ $UID -eq 0 ]] && symbols+="%{%F{$STATUS_ROOT}%}⚡"
+  [[ $(jobs -l | wc -l) -gt 0 ]] && symbols+="%{%F{$STATUS_JOBS}%}⚙"
+
+  [[ -n "$symbols" ]] && prompt_segment $STATUS_BG_COLOR $STATUS_FG_COLOR "$symbols"
+}
+
+# status for right prompt
+# - was good in green
+# - was wrong in red with error code
+prompt_r_status() {
+  local symbols
+  symbols=()
+  [[ $RETVAL -ne 0 ]] && symbols="%{%F{$STATUS_WRONG}%}\u2718 %? " || symbols="%{%F{$STATUS_OK}%}\u2714 %? "
+
+  prompt_right_segment $STATUS_BG_COLOR $STATUS_FG_COLOR "$symbols"
+}
+
+## Main prompt
+build_prompt() {
+  RETVAL=$?
+  prompt_status
+  prompt_context
+  prompt_dir
+  prompt_git
+  #prompt_hg
+  prompt_virtualenv
+  prompt_end
+}
+
+## Right prompt
+build_right_prompt() {
+  RETVAL=$?
+  prompt_right_segment $HOUR_BG_COLOR $HOUR_FG_COLOR "%D{%H:%M:%S}"
+  prompt_r_status
+}
+
+PROMPT='%{%f%b%k%}$(build_prompt) '
+RPROMPT='%{%f%b%k%}$(build_right_prompt)'